修改ramdisk卷标和磁盘格式的批处理
@echo offif "%OS%" == "Windows_NT" setlocal
color 2F
REM 设置文件系统格式(NTFS/FAT32/FAT):
set fs=FAT32
REM 设置卷标
set vn=Ramdisk
REM ------------------
set disk=
set keypos=HKLM\System\CurrentControlSet\Services\RRamdisk\Parameters\
echo 查找是否已安装 Ramdisk...
for /f "tokens=1 delims=:" %%i in ('reg query %keypos% /v DriveLetter') do set disk=%%i
if not "%disk%"=="" goto :regDisk
echo 运行本程序前,请先运行 ramdisk.exe
echo 安装 Ramdisk 并设置盘符和空间大小.
echo.
pause
:enterDisk
set /p disk=输入虚拟硬盘盘符(如R):
if "%disk%"=="" goto :enterDisk
:regDisk
set disk=%disk:~-1%
echo 虚拟硬盘盘符为 %disk%.
echo.
echo 格式化 %disk%:
set /p fs=输入文件系统类型(NTFS/FAT32/FAT),默认为 %fs% :
echo 文件系统类型是 %fs%
set /p vn=输入卷标,默认为 %vn% :
echo 卷标为 %vn%
FORMAT /FS:%fs% /X /Q /V:%vn% /A:512 %disk%:
if "%fs%"=="NTFS" CHKDSK /L:2048 %disk%:
echo.
echo.
echo ---------------------------------
echo 创建目录，你也可以手动创建 %disk% 盘文件或目录。
echo IE的缓存可以自动创建一个目录,你可不必创建。
echo.
:cf
set /p f=请输入目录名，留空继续下一步：
if not "%f%"=="" (
echo 创建目录 %disk%:\%f% ...
mkdir %disk%:\%f%
set f=
goto :cf
)
echo.
echo.
echo ---------------------------------
echo 正在保存目录结构到注册表,若看到"saving to registry...done.",说明无误...
echo.
rdutil %disk%: registry
echo.
echo 完成。
pause
修改ramdisk卷标和磁盘格式的批处理 不错的批处理提示未运行ramdisk
页:
[1]