Autoit3(AU3) 桌面图标位置设置

风一样的男孩

1. #NoTrayIcon
2. #Region ;**** 参数创建于 ACNWrapper_GUI ****
3. #AutoIt3Wrapper_icon=U:\autoit3\Aut2Exe\Icons\strawberry.ico
4. #AutoIt3Wrapper_outfile=AutoIcon.exe
5. #AutoIt3Wrapper_Compression=4
6. #AutoIt3Wrapper_Res_Comment=桌面图标设置
7. #AutoIt3Wrapper_Res_Description=网吧桌面图标设置
8. #AutoIt3Wrapper_Res_Fileversion=1.0.0.1
9. #AutoIt3Wrapper_Res_LegalCopyright=SxyNetBar
10. #EndRegion ;**** 参数创建于 ACNWrapper_GUI ****
11. #AutoIt3Wrapper_UseAnsi=y
13. #include <GuiListView.au3>
14. Opt("MustDeclareVars", 1)
15. Global $hWndManager = WinGetHandle("Program Manager")
16. Global $hWndDesktop = ControlGetHandle("Program Manager","",1)
17. If Not IsDeclared("GWL_STYLE") Then Global Const $GWL_STYLE = -16
18. Global $LVS_Style = _WinAPI_GetWindowLong($hWndDesktop, $GWL_STYLE)
19. Global $inifile, $iSet, $iRefresh, $SNAPTOGRID
21. If $CmdLine[0] Then
22.      For $i = 1 To $CmdLine[0]
23.          Select
24.              Case StringRegExp($CmdLine[$i], '^[/-](?i)load[=:].+$|^[/-](?i)l[=:].+$') And Not $inifile        
25.                  $iSet = 1
26.                  $inifile = StringRegExpReplace($CmdLine[$i], '^[/-](?i)load[=:]?|^[/-](?i)l[=:]?', "")
27.                
28.              Case StringRegExp($CmdLine[$i], '^[/-](?i)save[=:].+$|^[/-](?i)s[=:].+$') And Not $inifile
29.                  $iSet = 0
30.                  $inifile = StringRegExpReplace($CmdLine[$i], '^[/-](?i)save[=:]?|^[/-](?i)s[=:]?', "")
31.                
32.              Case StringRegExp($CmdLine[$i], '^[/-](?i)SnapToGrid[=:]\d+$|^[/-](?i)g[=:]\d+$') And $inifile        
33.                  $SNAPTOGRID = Number (StringRegExpReplace($CmdLine[$i], '^[/-](?i)SnapToGrid[=:]?|^[/-](?i)g[=:]?', "") )
34.                
35.              Case StringRegExp($CmdLine[$i], '^[/-](?i)Refresh$|^[/-](?i)r$')
36.                  $iRefresh = 1
37.                
38.              Case StringRegExp($CmdLine[$i], '^[/-](?i)Help$|^[/-](?i)[?h]$')
39.                  MsgBox(64,"参数帮助！","AutoIcon.exe [</load|/save>=<file>] [/G=<0|1>] [/R]" & @CRLF & "" & @CRLF & _
40.                      "/load=file 要加载的配置文件。" & @CRLF & "/save=file 要保存的配置文件。" & @CRLF & _
41.                          "/G=<0|1>   为“0”取消图标对齐到网格，为“1”图标对齐到网格，默认不作更改。" & @CRLF & "/R         相当于桌面右键“刷新”")
42.                  Exit
43.              Case Not $inifile
44.                  $inifile = $CmdLine[$i]
45.                  If FileExists($inifile) Then $iSet = 1
46.          EndSelect   
47.      Next
48. Else
49.      If Not IsDeclared("iMsgBoxAnswer") Then Dim $iMsgBoxAnswer
50.      $iMsgBoxAnswer = MsgBox(547,"注意！","" & @CRLF & "选“是”保存桌面图标位置信息到文件" & @CRLF & "" & @CRLF & "选“否”从文件读取并排列桌面图标。")
51.      Select
52.          Case $iMsgBoxAnswer = 6 ;Yes
53.              $inifile = FileSaveDialog( "输入一个文件名。", @ScriptDir, "配置文件(*.ini)", 2)
54.              If @error Or Not $inifile Then Exit
55.              $iSet = 0
56.              If Not StringRegExp($inifile, "\.ini$") Then $inifile &= ".ini"
57.          Case $iMsgBoxAnswer = 7 ;No
58.              $inifile = FileOpenDialog( "选择一个文件。", @ScriptDir, "配置文件(*.ini)", 1)
59.              If @error Or Not $inifile Then Exit
60.              $iSet = 1
61.          Case $iMsgBoxAnswer = 2 ;Cancel
62.              Exit
63.      EndSelect   
64. EndIf
66. If $iSet Then
67.      If $SNAPTOGRID Then $SNAPTOGRID = $LVS_EX_SNAPTOGRID
68.      If IsNumber ($SNAPTOGRID) Then _SendMessage($hWndDesktop, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_SNAPTOGRID, $SNAPTOGRID)
69.      If BitAND($LVS_Style, $LVS_AUTOARRANGE) Then _WinAPI_SetWindowLong($hWndDesktop, $GWL_STYLE, $LVS_Style - $LVS_AUTOARRANGE );取消自动排列
70.    
71.      If $iRefresh Then DllCall("shell32.dll", "none", "SHChangeNotify", "long", 0x8000000, "int", 0, "ptr", 0, "ptr", 0);刷新图标
72.      _SaveAndLoadIconPos($inifile, 1)
73.      ;Run("RunDll32.exe USER32.DLL,UpdatePerUserSystemParameters");刷新桌面(通过复制文件的方式替换壁纸文件适用)
74. Else
75.      _SaveAndLoadIconPos($inifile)
76. EndIf
78. Func _SaveAndLoadIconPos($iFile, $iLoad = 0)
79.      Local $iCount, $iIndex, $sName, $xy   
80.      If Not IsHWnd($hWndManager) Then $hWndManager = WinGetHandle("Program Manager")
81.      If Not IsHWnd($hWndDesktop) Then $hWndDesktop = ControlGetHandle("Program Manager","",1)
82.      $iCount = ControlListView($hWndManager, "", $hWndDesktop, "GetItemCount")
83.      If @error Then
84.          SetError(1)
85.          Return 0
86.      EndIf
87.      If Not $iLoad And FileExists($iFile) Then IniDelete($iFile, "图标位置")
88.      For $iIndex = 0 to $iCount - 1
89.          $sName = ControlListView($hWndManager, "", $hWndDesktop,"GetText", $iIndex)
90.          If $iLoad Then
91.              $xy = StringSplit (IniRead ($iFile, "图标位置", $sName, ""), ",")
92.              If $xy[0] = 2 Then _
93.              _SendMessage($hWndDesktop, $LVM_SETITEMPOSITION, $iIndex, BitOR(BitShift($xy[2], -16), BitAND($xy[1], 0xffff) ) )
94.          Else;保存图标信息
95.              $xy = _GUICtrlListView_GetItemPosition($hWndDesktop, $iIndex)
96.              IniWrite($iFile, "图标位置", $sName, $xy[0] & "," & $xy[1] )
97.          EndIf   
98.      Next
99.      Return 1
100. EndFunc

复制代码